home *** CD-ROM | disk | FTP | other *** search
/ The PC-SIG Library 9 / The PC-SIG Library on CD ROM - Ninth Edition.iso / 001_100 / DISK0041 / DISK0041.ZIP / MSKERM.ASM < prev    next >
Assembly Source File  |  1984-12-08  |  36KB  |  1,425 lines
  1.     public    prompt, dosnum, curdsk, fpush
  2.     include msdefs.h
  3. ;******************** Version 2.27 ********************************** 
  4. ; KERMIT, Celtic for "free" 
  5. ;
  6. ; The name "Kermit" is a registered trade mark of Henson Associates, Inc.,
  7. ; used by permission.
  8. ; 
  9. ;       Kermit-MS Program Version 2.27, December 6,1984
  10. ; 
  11. ;       Based on the Columbia University KERMIT Protocol.
  12. ; 
  13. ;       Copyright (C) 1982,1983,1984 Trustees of Columbia University
  14. ;
  15. ;       Daphne Tzoar, Jeff Damens
  16. ;       Columbia University Center for Computing Activities
  17. ;       612 West 115th Street
  18. ;       New York, NY  10025
  19. ; 
  20. ; Special thanks to Frank da Cruz, Bill Catchings, Steve Jensen, Herm Fischer,
  21. ; Vace Kundakci, and Bernie Eiben for their help and contributions.
  22.  
  23. makseg    equ    26H
  24. deffcb    equ    5cH
  25. setblk    equ    4AH
  26. exec    equ    4BH
  27. env    equ    2CH        ; environment address in psp
  28. terma    equ    10        ; termination address in psp
  29. cline    equ    80H        ; offset in psp of command line
  30. namsiz    equ    20        ; Bytes for file name and size.
  31. maxnam    equ    10
  32. chmod    equ    43H        ; chmod call (used to test for file existence)
  33.  
  34. STACK   SEGMENT PARA STACK 'STACK'
  35.         DW      100 DUP(0)      ; Initialize stack to all zeros.
  36. STK    EQU    THIS WORD
  37. STACK   ENDS
  38.  
  39. datas   segment public 'datas'
  40.     extrn    buff:byte, comand:byte, flags:byte, pack:byte, trans:byte
  41.     extrn    fcb:byte, cpfcb:byte, prmptr:word, inichk:byte
  42.     extrn    machnam:byte
  43.     public    takadr,taklev
  44.  
  45. versio    label    byte
  46.     verdef
  47.     db    cr,lf
  48.     db    'Type ? for help',cr,lf
  49.     db    '$'
  50. tmp    db    ?,'$'
  51. crlf    db      cr,lf,'$'
  52. ermes1  db      cr,lf,'?Unrecognized command$'
  53. ermes3  db      cr,lf,'?Not confirmed$'
  54. erms30    db    cr,lf,'Passed maximum nesting level for TAKE command$'
  55. erms31    db    cr,lf,'Take file not found$'
  56. erms32    db    cr,lf,'File(s) not found$'
  57. erms33    db    cr,lf,'CHKDSK program not found on current disk$'
  58. erms34    db    cr,lf,'This command works only for DOS 2.0 and above$'
  59. erms35    db    cr,lf,'Must specify program name$'
  60. erms36    db    cr,lf,'Could not free memory$'
  61. erms37    db    cr,lf,'Unable to execute program$'
  62. infms1    db    'Really erase *.*? $'
  63. infms8    db    cr,lf,'File(s) erased$'
  64. tmsg5    db    cr,lf,'[closing log file]',cr,lf,'$' ; [jd]
  65. filhlp1 db      ' Command file specification $'
  66. filhlp2 db      ' File specification (possibly wild) $'
  67. filhlp3    db    ' File spec (possibly wild) or confirm with carriage return$'
  68. filmsg    db    ' File specification with optional path name $'
  69. filwmsg    db    ' File specification (possibly wild) with optional path name $'
  70. chkfil    db    0,'CHKDSK  COM'
  71. chkflen    equ    $-chkfil
  72.  
  73. tophlp  db    cr,lf
  74.     db    'BYE',tab,tab
  75.     db    'CLOSE',tab,tab
  76.     db      'CONNECT',tab,tab
  77.     db    'DEFINE',tab,tab
  78.     db    cr,lf
  79.     db    'DELETE',tab,tab
  80.     db    'DIRECTORY',tab
  81.     db    'DO',tab,tab
  82.         db      'EXIT',tab,tab
  83.     db    cr,lf
  84.     db    'FINISH',tab,tab
  85.     db    'GET',tab,tab
  86.         db      'HELP',tab,tab
  87.     db    'LOCAL',tab,tab
  88.     db    cr,lf
  89.     db    'LOG',tab,tab
  90.     db    'LOGOUT',tab,tab
  91.     db    'PUSH',tab,tab
  92.         db      'QUIT',tab,tab
  93.     db    cr,lf
  94.         db      'RECEIVE',tab,tab
  95.     db    'REMOTE',tab,tab
  96.     db    'RUN',tab,tab
  97.         db      'SEND',tab,tab
  98.     db    cr,lf
  99.     db    'SERVER',tab,tab
  100.         db      'SET',tab,tab
  101.     db    'SHOW',tab,tab
  102.     db    'SPACE',tab,tab
  103.     db    cr,lf
  104.         db      'STATUS',tab,tab
  105.     db    'TAKE'
  106.     db    '$'
  107.  
  108. lochlp    db    cr,lf,'DELETE file'
  109.     db    cr,lf,'DIRECTORY [filespec]'
  110.     db    cr,lf,'SPACE remaining on current disk'
  111.     db    cr,lf,'RUN program'
  112.     db    cr,lf,'PUSH to command interpreter'
  113.     db    '$'
  114.  
  115.         ; COMND tables
  116.  
  117. yestab    db    2
  118.     mkeyw    'NO',0
  119.     mkeyw    'YES',1
  120.  
  121. comtab  db    27
  122.     mkeyw    'BYE',bye
  123.     mkeyw    'C',telnet
  124.     mkeyw    'CLOSE',clscpt
  125.     mkeyw    'CONNECT',telnet
  126.     mkeyw    'DEFINE',dodef
  127.     mkeyw    'DELETE',delete
  128.     mkeyw    'DIRECTORY',direct
  129.     mkeyw    'DO',docom
  130.     mkeyw    'EXIT',exit
  131.     mkeyw    'FINISH',finish
  132.     mkeyw    'GET',get
  133.     mkeyw    'HELP',help
  134.     mkeyw    'LOCAL',lclcmd
  135.     mkeyw    'LOG',setcpt
  136.     mkeyw    'LOGOUT',logout
  137.     mkeyw    'PUSH',dopush
  138.     mkeyw    'QUIT',exit
  139.     mkeyw    'RECEIVE',read
  140.     mkeyw    'REMOTE',remote
  141.     mkeyw    'RUN',run
  142.     mkeyw    'SEND',send
  143.     mkeyw    'SERVER',server
  144.     mkeyw    'SET',setcom
  145.     mkeyw    'SHOW',showcmd
  146.     mkeyw    'SPACE',chkdsk
  147.     mkeyw    'STATUS',status
  148.     mkeyw    'TAKE',take
  149.  
  150. loctab    db    5
  151.     mkeyw    'DELETE',delete
  152.     mkeyw    'DIRECTORY',direct
  153.     mkeyw    'PUSH',dopush
  154.     mkeyw    'RUN',run
  155.     mkeyw    'SPACE',chkdsk
  156.  
  157. shotab    db    2
  158.     mkeyw    'KEY',shokey
  159.     mkeyw    'MACROS',shomac
  160.  
  161. ; Program storage.
  162.  
  163. oldstk  dw      ?               ; Storage for system stack.
  164. oldsts  dw      ?               ; System stack segment.
  165. ssave    dw    ?        ; Original SS when doing CHKDSK.
  166. siz    dw    ?        ; Memory size.
  167. in3ad    dd    0        ; Original break interrupt addresses. [25]
  168. curdsk    db    0        ; Current disk. 
  169. origd    db    0        ; Original disk.
  170. fildat    db    0        ; Manipulate file data/time creation.
  171.     db    0
  172. taklev    db    0        ; Take levels. [25t]
  173. takadr    dw    takstr-(size takinfo) ; Pointer into structure. [25t]
  174. temp    dw    0
  175. temp1   dw      ?               ; Temporary storage.
  176. temp2   dw      ?
  177. temp3   dw      ?
  178. temp4   dw      ?
  179. psp    dw    ?
  180. divst    dw    0    
  181. takstr    db    (size takinfo) * maxtak dup(?)
  182. ininam    db    0,'MSKERMITINI'    ; init file name, on default disk, 12 chars
  183. ininm2    db    'MSKERMIT.INI',0 ; init file name for 2.0
  184. nambuf    db    maxnam * namsiz dup (?)
  185. cmdnam    db    namsiz dup (?)
  186. exefcb    db    fcbsiz dup (?)
  187. exefcb2    db    fcbsiz dup (?)
  188. exearg    dw    ?        ; segment addr of environment (filled in below)
  189.     dd    0        ; ptr to cmd line (filled in below)
  190.     dd    exefcb        ; default fcb
  191.     dd    exefcb2        ; second default fcb
  192. dircmd    db    ' /c dir '
  193. dirclen    equ    $-dircmd
  194. dirnam    db    50h dup (?)
  195. chkdcmd    db    'chkdsk.com'
  196. chkdlen    equ    $-chkdcmd
  197. dosnum    db    ?        ; dos version number
  198. pthnam    db    'PATH='
  199. pthlen    equ    $-pthnam
  200. pthbuf    db    100 dup (?)    ; buffer for path definition.
  201. defpth    db    '\', 70 dup (?)    ; buffer for default path
  202. cmspnam    db    'COMSPEC='
  203. cmsplen    equ    $-cmspnam
  204. cmspbuf    db    '\command.com',0 ; default name
  205.     db    30 dup (?)    ; some additional space
  206. tfile    db    100 dup (?)    ; temp space for file names.
  207. eexit    db    cr,'exit',cr
  208. leexit    equ    $-eexit
  209. datas   ends                    ; End data segment
  210.  
  211. code    segment    public 
  212.     public    takrd
  213. start   proc  far
  214.     extrn    cmblnk:near, locate:near, logout:near
  215.     extrn    bye:near, telnet:near, finish:near, comnd:near
  216.     extrn    read:near, remote:near, send:near, status:near, get:near
  217.     extrn    dodisk:near, serrst:near, setcom:near
  218.     extrn    clscpi:near, clscpt:near, getbaud:near
  219.     extrn    dodef:near, setcpt:near, docom:near
  220.     extrn    server:near, lclini:near, shokey:near, shomac:near
  221.     extrn    packlen:near
  222.         assume  cs:code,ds:datas,ss:stack,es:nothing
  223.  
  224.         push ds                 ; Save system data area.
  225.         sub ax,ax               ; Get a zero.
  226.         push ax                 ; Put zero return addr on stack.
  227.  
  228.     mov ax,datas           ; Initialize DS.
  229.         mov ds,ax
  230.     sub ax,ax
  231.  
  232.         mov oldstk,sp           ; Save old stack pointer.
  233.  
  234.     mov ax,es:[2]        ; In program segment prefix
  235.     mov siz,ax        ; Pick up memory size
  236.     mov psp,es    
  237.  
  238.     mov ah,prstr
  239.     mov dx,offset machnam    ; print machine name
  240.     int dos
  241.         mov ah,prstr            ; Print the version header.
  242.         mov dx,offset versio
  243.         int dos
  244.  
  245.     mov ah,setdma        ; Set disk transfer address.
  246.     mov dx,offset buff
  247.     int dos
  248.  
  249.     call getbaud        ; Get the baud rate. [25]
  250.     call dodisk        ; See how many disk drives we have. [21a]
  251.     call setint
  252.     mov ah,gcurdsk        ; Get current disk.
  253.     int dos
  254.     inc al            ; We want 1 == A (not zero).
  255.     mov curdsk,al
  256.     mov origd,al        ; Remember original disk we started on.
  257.     mov ah,dosver
  258.     int dos
  259.     mov dosnum,al        ; remember dos version
  260.     cmp al,0
  261.     je start1        ; 1.1, keep going
  262.     mov es,psp
  263.     mov ax,es:[env]        ; pick up environment address
  264.     push ax
  265.     call getpath        ; get the path from the environment
  266.     pop ax            ; get environment back
  267.     call getcsp        ; get comspec from environment as well
  268. start1:    call lclini        ; do local initialization
  269.     call gcmdlin        ; read command line
  270.     call rdinit        ; read kermit init file
  271.     call packlen        ; Packet length in case do server comand.
  272. ; This is the main KERMIT loop.  It prompts for and gets the users commands.
  273.  
  274. kermit:    mov ax,ds
  275.     mov es,ax        ; make sure this addresses data segment
  276.     mov dx,prmptr        ; get prompt
  277.     call prompt             ; Prompt the user.
  278.     mov pack.state,0    ; Clear the state.
  279.     mov flags.cxzflg,0    ; Reset each itme.
  280.     mov ah,inichk        ; Original or set checksum length.
  281.     mov trans.chklen,ah    ; Reset just in case.
  282.         mov dx,offset comtab
  283.         mov bx,offset tophlp
  284.     mov comand.cmcr,1    ; Allow bare CR's.
  285.         mov ah,cmkey
  286.         call comnd
  287.          jmp kermt2
  288.     mov comand.cmcr,0    ; Not anymore.
  289.         call bx                 ; Call the routine returned.
  290.          jmp kermt3
  291.     cmp flags.extflg,0    ;  Check if the exit flag is set.
  292.     jne krmend        ;  If so jump to KRMEND.
  293.     jmp kermit        ; Do it again.
  294.  
  295. kermt2:    mov dx,offset ermes1    ;  Give an error.
  296.     jmp short kermt4
  297.  
  298. kermt3:    mov dx,offset ermes3    ;  Give an error.
  299. kermt4:    cmp flags.cxzflg,'C'    ; some sort of abort?
  300.     je kermit        ; yes, don't print error message.
  301.     mov ah,prstr
  302.     int dos
  303.     mov flags.droflg,0    ; Reset drive override flag.
  304.     mov flags.nmoflg,0    ; Reset filename override flag.
  305.     mov flags.getflg,0    ; May as well do this one.
  306.     mov flags.cmrflg,0    ; This one too.
  307.     jmp kermit
  308.  
  309. krmend: call serrst        ; Just in case the port wasn't reset. [21c] 
  310.     mov dl,origd        ; Original disk drive.
  311.     dec dl            ; Want A == 0.
  312.     mov ah,seldsk        ; Reset original disk just in case.
  313.     int dos
  314.     mov sp,oldstk
  315.     ret
  316.  
  317. START    ENDP
  318.  
  319. ; This is the 'exit' command.  It leaves KERMIT and returns to DOS.
  320.  
  321. EXIT    PROC    NEAR
  322.     mov ah,cmcfm
  323.     call comnd        ; Get a confirm.
  324.      jmp r
  325.     test    flags.capflg,0FFH    ; capturing?
  326.     jz    exit1            ; no, keep going
  327.     mov    dx,offset tmsg5
  328.     mov    ah,prstr
  329.     int    dos
  330.     call    clscpi
  331.      nop                ; this skip returns...
  332.      nop
  333.      nop
  334. exit1:
  335.     mov flags.extflg,1    ;  Set the exit flag.
  336.     jmp rskp        ; Then return to system.
  337. EXIT    ENDP
  338.  
  339.  
  340. ; This is the 'help' command.  It gives a list of the commands.
  341.  
  342. HELP    PROC    NEAR
  343.     mov ah,cmcfm
  344.     call comnd        ; Get a confirm.
  345.      jmp r
  346.     mov ah,prstr        ; Print a string to the console.
  347.     mov dx,offset tophlp    ; The address of the help message.
  348.     int dos
  349.     jmp rskp
  350. HELP    ENDP
  351.  
  352. lclcmd    proc    near
  353.     mov ah,cmkey
  354.     mov dx,offset loctab
  355.     mov bx,offset lochlp
  356.     call comnd
  357.      jmp r
  358.     call bx
  359.     nop
  360.     nop
  361.     nop
  362.     jmp rskp
  363. lclcmd    endp
  364.  
  365. ; Don't ignore ^C when in debug mode.
  366. SETINT    PROC    NEAR
  367.     push ds            ; Don't forget this. [25]
  368.     mov ax,ds
  369.     mov es,ax        ; So can access our data area.
  370.     mov ax,0
  371.     mov ds,ax        ; Access low core.
  372.     mov ax,ds:[23H * 4]    ; Address for interrupt 23H.
  373.     mov cx,ds:[23H * 4 +2]    ; CS value for it.
  374.     mov word ptr es:in3ad,ax ; Remember original values.
  375.     mov word ptr es:in3ad+2,cx
  376.     mov ax,cs
  377.     mov ds,ax        ; Access code are.
  378.     mov dx,offset intbrk
  379.     mov al,23H        ; On ^C, goto above address.
  380.     mov ah,25H
  381.     int dos
  382.     pop ds
  383.     ret
  384. SETINT    ENDP
  385.  
  386. ; take commands from a file, but allow a path name
  387. PTAKE    PROC    NEAR
  388.     cmp taklev,maxtak        ; Hit our limit?
  389.     jl ptake1            ; Continue if still OK.
  390.     mov ah,prstr
  391.     mov dx,offset erms30        ; Complain.
  392.     int dos 
  393.     ret
  394. ptake1:    mov di,takadr
  395.     add di,size takinfo
  396.     push di
  397.     mov ah,cmtxt
  398.     lea bx,[di].takbuf        ; convenient place to parse name into
  399.     mov dx,offset filmsg        ; Help in case user types "?".
  400.     call comnd
  401.      pop di
  402.      ret
  403.      nop
  404.     pop di                ; restore frame address
  405.     cmp ah,0
  406.     je ptake2            ; empty, complain.
  407.     push di                ; keep it on stack.
  408.     lea si,[di].takbuf        ; get buffer back
  409.     mov bl,ah            ; length of thing parsed
  410.     mov bh,0
  411.     mov byte ptr [bx+si],0        ; make it asciz
  412.     mov ax,si            ; point to name again
  413.     call spath            ; is it around?
  414.     pop di                ; need this back
  415.     jc ptake2            ; no, go complain
  416.     mov dx,ax            ; point to name from spath
  417.     mov ah,open2            ; 2.0 open call
  418.     mov al,0            ; open for reading
  419.     int dos
  420.     jnc ptake3            ; open ok, keep going
  421. ptake2:    mov ah,prstr
  422.     mov dx,offset erms31
  423.     int dos
  424.     ret
  425. ptake3:    inc taklev
  426.     mov takadr,di
  427.     mov word ptr [di].takfcb+1,ax    ; save file descriptor
  428.     mov byte ptr [di].takfcb,0feh    ; mark as 2.0 file descriptor
  429.     mov bx,ax            ; need descriptor here
  430.     mov ah,lseek
  431.     mov al,2
  432.     mov cx,0
  433.     mov dx,cx            ; seek 0 bytes from end
  434.     int dos
  435.     mov [di].takcnt,ax
  436.     mov [di].takcnt+2,dx        ; store length
  437.     mov ah,lseek
  438.     mov al,0
  439.     mov cx,0
  440.     mov dx,cx            ; now seek back to beginning
  441.     int dos
  442.     cmp flags.takflg,0
  443.     je ptake4
  444.     mov ah,prstr
  445.     mov dx,offset crlf
  446.     int dos
  447. ptake4:    call takrd        ; Get a buffer full of data.
  448.     jmp rskp
  449. PTAKE    ENDP
  450.  
  451.  
  452. ;     TAKE commands from a file.  [25t]
  453.  
  454. TAKE    PROC    NEAR
  455.     cmp dosnum,0
  456.     je take1
  457.     jmp ptake            ; use this for 2.0
  458. take1:    cmp taklev,maxtak        ; Hit our limit?
  459.     jl take2                ; Continue if still OK.
  460.     mov ah,prstr
  461.     mov dx,offset erms30        ; Complain.
  462.     int dos 
  463.     ret
  464. take2:    mov bx,takadr
  465.     add bx,size takinfo
  466.     push bx
  467.     lea dx,[bx].takfcb
  468.      mov comand.cmcr,0        ; Filename must be specified.
  469.     mov ah,cmifi
  470.     mov bx,offset filhlp1
  471.     call comnd
  472.      pop bx
  473.      ret                ; Make sure this is three bytes long.
  474.      nop
  475.     pop bx
  476.     mov byte ptr [bx].takfcb+32,0    ; have to clear current record in fcb
  477.     mov ah,openf
  478.     lea dx,[bx].takfcb
  479.     int dos
  480.     cmp al,0FFH            ; File not found?
  481.     jne take3
  482.     mov ah,prstr
  483.     mov dx,offset erms31
  484.     int dos
  485. take3:    inc taklev
  486.     mov takadr,bx
  487.     mov ax,word ptr [bx+16].takfcb
  488.     mov [bx].takcnt,ax
  489.     mov ax,word ptr [bx+18].takfcb
  490.     mov [bx].takcnt+2,ax        ; copy size into takinfo
  491.     cmp flags.takflg,0
  492.     je take4
  493.     mov ah,prstr
  494.     mov dx,offset crlf
  495.     int dos
  496. take4:    call takrd            ; Get a buffer full of data.
  497.     jmp rskp
  498. TAKE     ENDP
  499.  
  500. TAKRD    PROC    NEAR
  501.     push bx
  502.     push cx    
  503.     push dx
  504.     mov bx,takadr
  505.     cmp byte ptr [bx].takfcb,0feh    ; is it a 2.0 file handle?
  506.     jne takrd1            ; no, handle differently
  507.     push bx                ; save frame address
  508.     lea dx,[bx].takbuf        ; buffer to read into
  509.     mov cx,dmasiz            ; # of bytes to read
  510.     mov ah,readf2            ; 2.0 read call
  511.     mov bx,word ptr [bx].takfcb+1    ; file handle is stored here
  512.     int dos
  513.     pop bx                ; restore frame address
  514.     jmp takrd2            ; rejoin common exit
  515.  
  516. takrd1:    mov ah,setdma
  517.     lea dx,[bx].takbuf
  518.     int dos
  519.     mov ah,readf
  520.     lea dx,[bx].takfcb
  521.     int dos
  522.     mov ah,setdma
  523.     lea dx,buff
  524.     int dos
  525. takrd2:    mov [bx].takchl,dmasiz
  526.     lea ax,[bx].takbuf
  527.     mov [bx].takptr,ax
  528.     pop dx
  529.     pop cx
  530.     pop bx
  531.     ret
  532.  
  533. TAKRD    ENDP
  534.  
  535. ; copy the path into pthbuf
  536. ; enter with ax/ environment segment address
  537. ; works in 2.0 only.
  538. getpath    proc    near
  539.     push    es
  540.     mov    bx,ds
  541.     mov    es,bx            ; address data segment
  542.     mov    bx,offset pthnam    ; thing to find
  543.     mov    cx,pthlen        ; length of it
  544.     mov    dx,offset pthbuf    ; place to put it
  545.     mov    byte ptr pthbuf,0    ; initialize to null...
  546.     call    getenv            ; get environment value
  547.     pop    es
  548.     ret                ; and return
  549. getpath    endp
  550.  
  551. ; copy the comspec into cmspbuf
  552. ; enter with ax/ environment segment address
  553. ; works in 2.0 only.
  554. getcsp    proc    near
  555.     push    es
  556.     mov    bx,ds
  557.     mov    es,bx            ; address data segment
  558.     mov    bx,offset cmspnam    ; thing to find
  559.     mov    cx,cmsplen        ; length of it
  560.     mov    dx,offset cmspbuf    ; place to put it
  561.     call    getenv            ; get environment value
  562.     pop    es
  563.     ret                ; and return
  564. getcsp    endp
  565.  
  566. ; find a path variable.  Enter with ax/ environment segment,
  567. ; bx/ variable to find (incl =), cx/ length of variable name,
  568. ; dx/ address to store value at.
  569. ; The buffer given in dx is unchanged if the variable isn't found
  570. getenv    proc    near
  571.     push    ds
  572.     push    es
  573.     mov    es,ax            ; address segment
  574.     mov    di,0            ; offset in segment
  575. geten1:    cmp    es:byte ptr [di],0    ; end?
  576.     je    geten4            ; yes, forget it
  577.     push    cx            ; save counter
  578.     push    di            ; and offset
  579.     mov    si,bx
  580.     repe    cmpsb            ; is it the one?
  581.     pop    di
  582.     pop    cx            ; restore these
  583.     je    geten2            ; found it, break loop
  584.     push    cx            ; preserve again
  585.     mov    cx,0ffffh        ; bogus length
  586.     mov    al,0            ; marker to look for
  587.     repne    scasb            ; search for it
  588.     pop    cx            ; restore length
  589.     jmp    geten1            ; loop thru rest of environment
  590. geten2:    add    di,cx            ; skip to definition
  591.     mov    si,di            ; this is source
  592.     mov    di,dx            ; destination as given
  593.     mov    ax,ds
  594.     mov    bx,es
  595.     mov    ds,bx
  596.     mov    es,ax            ; exchange segment regs for copy
  597. geten3:    lodsb                ; get a byte
  598.     stosb                ; drop it off
  599.     cmp    al,0            ; end of string
  600.     jne    geten3            ; no, go on
  601. geten4:    pop    es
  602.     pop    ds            ; restore registers
  603.     ret                ; and return
  604. getenv    endp
  605.  
  606. ; put kermit.ini onto take stack if it exists.  Just like
  607. ; the take command, except it doesn't read a filename.
  608.  
  609. rdinit    proc    near        ; read kermit init file...
  610.     mov al,dosnum        ; get dos version
  611.     or al,al
  612.     jne rdini4        ; post 2.0, use file handle instead...
  613.     mov bx,takadr
  614.     add bx,size takinfo    ; bump take ptr, point to current take frame
  615.     lea di,[bx].takfcb    ; destination is fcb
  616.     mov ax,ds
  617.     mov es,ax        ; destination segment = source segment
  618.     mov si,offset ininam    ; name of init file
  619.     mov cx,12        ; 8 char name + 3 char ext + 1 char drive...
  620.     rep movsb        ; copy it in
  621.     mov byte ptr [bx].takfcb+32,0 ; have to clear current record in fcb
  622.     mov ah,openf
  623.     lea dx,[bx].takfcb
  624.     int dos
  625.     cmp al,0FFH        ; File not found?
  626.     jne rdini1        ; no, keep going
  627.     ret            ; else just return, no init file
  628. rdini1:    inc taklev        ; bump take level
  629.     mov takadr,bx        ; save current take frame ptr
  630.     mov ax,word ptr [bx+16].takfcb
  631.     mov [bx].takcnt,ax
  632.     mov ax,word ptr [bx+18].takfcb
  633.     mov [bx].takcnt+2,ax    ; copy size into takinfo
  634. rdini2:    cmp flags.takflg,0
  635.     je rdini3
  636.     mov ah,prstr
  637.     mov dx,offset crlf
  638.     int dos
  639. rdini3:    call takrd        ; Get a buffer full of data.
  640.     ret
  641.  
  642. rdini4:    mov ax,offset ininm2    ; name to try
  643.     push bx
  644.     call spath        ; can we find it?
  645.     pop di
  646.     jc rdini6        ; no, forget it, go use it
  647.     mov dx,ax        ; point to name
  648.     mov ah,open2        ; 2.0 open function
  649.     mov al,0        ; for reading...
  650.     int dos
  651.     jc rdini6        ; can't open, forget it
  652.  
  653. rdini5:    inc taklev        ; bump take level
  654.     add takadr,size takinfo
  655.     mov di,takadr        ; get current frame ptr
  656.     mov word ptr [di].takfcb+1,ax    ; save file handle
  657.     mov byte ptr [di].takfcb,0feh    ; mark as a handle
  658.     mov bx,ax            ; move file ptr
  659.     mov ah,lseek
  660.     mov al,2
  661.     mov cx,0
  662.     mov dx,0            ; seek to end of file
  663.     int dos
  664.     mov [di].takcnt,ax        ; copy file size
  665.     mov [di].takcnt+2,dx        ; into structure
  666.     mov al,0
  667.     mov ah,lseek
  668.     mov cx,0
  669.     mov dx,0
  670.     int dos                ; seek back to beginning
  671.     jmp rdini2            ; go rejoin common exit
  672. rdini6:    ret                ; no init file, just return
  673. rdinit    endp
  674.  
  675. ; get command line into a macro buffer.
  676.  
  677. gcmdlin    proc    near
  678.     push    ds
  679.     push    es
  680.     cld
  681.     mov    es,psp            ; address psp
  682.     mov    ch,0
  683.     mov    cl,es:[cline]        ; length of cmd line
  684.     mov    di,cline+1        ; point to actual line
  685.     mov    al,' '
  686.     jcxz    gcmdl3            ; no command line, forget it.
  687.     repe    scasb            ; skip over spaces
  688.     je    gcmdl3            ; all spaces, forget it
  689.     mov    si,di            ; this is first non-space
  690.     dec    si            ; pre-incremented...
  691.     inc    cx
  692.     inc    taklev            ; bump take level
  693.     add    takadr,size takinfo    ; address new take frame
  694.     mov    bx,takadr
  695.     mov    byte ptr [bx].takfcb,0ffh ; mark as a macro
  696.     push    cx            ; save length
  697.     push    ds            ; and segment
  698.     lea    di,[bx].takbuf        ; into take buffer
  699.     mov    ax,ds
  700.     mov    ds,psp
  701.     mov    es,ax            ; switch segments for copy
  702. gcmdl1:    lodsb                ; get a byte
  703.     cmp    al,','            ; comma?
  704.     jne    gcmdl2            ; no, keep going
  705.     mov    al,cr            ; convert to cr
  706. gcmdl2:    stosb                ; deposit it
  707.     loop    gcmdl1            ; copy whole cmd
  708.     pop    ds            ; restore segment
  709.     mov    si,offset eexit        ; something to tack onto end
  710.     mov    cx,leexit        ; length of it
  711.     rep    movsb            ; copy it in
  712.     pop    cx            ; restore len
  713.     add    cx,leexit        ; count wnat we added
  714.     
  715.     lea    ax,[bx].takbuf
  716.     mov    [bx].takptr,ax        ; init buffer ptr
  717.     mov    [bx].takchl,cl        ; chars remaining
  718.     mov    [bx].takcnt,cx        ; and all chars
  719.     mov    [bx].takcnt+2,0        ; clear high order
  720. gcmdl3:    pop    es
  721.     pop    ds
  722.     ret
  723. gcmdlin    endp
  724.  
  725. ;    This routine prints the prompt and specifies the reparse address.
  726.  
  727. PROMPT    PROC  NEAR
  728.     mov comand.cmprmp,dx    ; save the prompt
  729.     pop bx            ; Get the return address.
  730.     mov comand.cmrprs,bx    ; Save as addr to go to on reparse.
  731.     mov comand.cmostp,sp    ; Save for later restoral.
  732.     push bx            ; Put it on the stack again.
  733.     mov bx,offset comand.cmdbuf
  734.     mov comand.cmcptr,bx    ; Initialize the command pointer.
  735.     mov comand.cmdptr,bx
  736.     mov ah,0
  737.     mov comand.cmaflg,ah    ; Zero the flags.
  738.     mov comand.cmccnt,ah
  739.     mov comand.cmsflg,0FFH
  740.     cmp flags.takflg,0    ; look at take flag
  741.     jne promp1        ; supposed to echo, skip this check...
  742.     cmp taklev,0        ; inside a take file?
  743.     je promp1        ; no, keep going
  744.     ret            ; yes, return
  745. promp1:    mov ah,prstr
  746.     mov dx,offset crlf
  747.     int dos
  748.     mov ah,prstr        ; Print the prompt.
  749.     mov dx,comand.cmprmp
  750.     int dos
  751.     ret
  752. PROMPT    ENDP
  753.  
  754. ; Erase specified file(s).
  755. DELETE    PROC    NEAR
  756.      mov comand.cmcr,0    ; Filename must be specified.
  757.     mov ah,cmifi        ; Parse an input filespec.
  758.     mov dx,offset fcb
  759.     mov bx,offset filhlp2    ; Text of help message.
  760.     call comnd
  761.      jmp r            ; Bad filename.
  762.     mov ah,cmcfm        ; Parse a confirm.
  763.     call comnd
  764.      jmp r
  765.     cld
  766.     mov di,offset fcb+1
  767.     mov al,'?'
  768.     mov cx,11        ; # of chars in a name
  769.     repe scasb        ; are they all ?'s?
  770.     jne del1        ; no, skip message
  771.     mov dx,offset infms1
  772.     call prompt
  773.     mov ah,cmkey
  774.     mov dx,offset yestab
  775.     mov bx,0
  776.     call comnd
  777.      jmp r
  778.     push bx
  779.     mov ah,cmcfm
  780.     call comnd
  781.      pop bx
  782.      ret
  783.      nop
  784.     pop bx
  785.     cmp bx,0
  786.     jne del1
  787.     jmp rskp
  788. del1:    mov dx,offset fcb
  789.     mov ah,sfirst        ; See if any files match this specification.
  790.     int dos    
  791.     cmp al,0FFH        ; No matches?
  792.     jne del2
  793.     mov ah,prstr
  794.     mov dx,offset erms32
  795.     int dos
  796.     jmp rskp
  797. del2:    mov dx,offset fcb
  798.     mov ah,delf        ; Erase the file(s).
  799.     int dos
  800.     mov dx,offset infms8
  801.     mov ah,prstr        ; Say we did so.
  802.     int dos
  803.     jmp rskp
  804. DELETE    ENDP    
  805.  
  806. CHKDSK    PROC    NEAR
  807.     mov ah,cmcfm
  808.     call comnd
  809.      jmp r
  810.     cmp dosnum,0
  811.     je chkds1            ; yes, have to do it the hard way
  812.     mov si,offset chkdcmd        ; point to cmd
  813.     mov cx,chkdlen            ; and length
  814.     jmp crun            ; and go execute it nicely
  815. chkds1:    push es
  816.     mov ax,ds
  817.     mov es,ax
  818.     mov di,offset fcb
  819.     mov si,offset chkfil
  820.     mov cx,chkflen
  821.     rep movsb
  822.     mov dx,offset stk + 15        ; End of stack plus roundoff.
  823.     mov cl,4
  824.     shr dx,cl            ; Divide to get segment.
  825.     add dx,seg stack        ; Get past the stack.
  826.     mov es,dx            ; remember where segment is.
  827.     mov ah,makseg            ; Create new PSP.
  828.     int dos
  829.     mov ax,siz            ; Update machine size.
  830.     mov es:2,ax
  831.     mov es: byte ptr [deffcb],0    ; Blank default fcb.
  832.     mov di,deffcb+1
  833.     mov al,' '            ; Blank out fcb.
  834.     mov cx,fcbsiz
  835.     rep stosb
  836.     mov word ptr es:[terma],offset term    ; Termination address.
  837.     mov es:[terma+2],cs
  838.     mov ah,openf
  839.     mov dx,offset fcb
  840.     int dos
  841.     inc al
  842.     jnz chkok
  843.     mov dx,offset erms33
  844.     mov ah,prstr
  845.     int dos
  846.     jmp chkend
  847.  
  848. chkok:    mov byte ptr fcb+32,0        ; set current record field
  849.     mov di,100h            ; offset to copy into
  850. lp:    mov dx,offset fcb
  851.     mov ah,readf
  852.     int dos
  853.     push ax                ; save status
  854.     mov si,offset buff
  855.     mov cx,dmasiz/2            ; Word size of DMA
  856.     rep movsw            ; copy into new segment...
  857.     pop ax
  858.     cmp al,1            ; End of file
  859.     je dun
  860.     cmp al,3            ; Done here too
  861.     jne lp
  862. dun:    mov ssave,sp            ; Save stack pointer.
  863.     mov ax,es
  864.     mov word ptr cs:[doit+2],ax     ; Set segment for CHKDSK.
  865.     mov ds,ax
  866.     mov ss,ax
  867.     mov ax,0
  868.     jmp cs: dword ptr [doit]    ; Call CHKDSK.
  869. term:    mov ax,seg datas        ; Reset data area.
  870.     mov ds,ax
  871.     mov sp,ssave
  872.     mov ax,seg stack
  873.     mov ss,ax
  874.     mov ah,setdma
  875.     mov dx,offset buff
  876.     int dos                ; restore dma address!!
  877. chkend:    pop es
  878.     jmp rskp
  879. doit    dd 100h
  880. CHKDSK    ENDP
  881.  
  882. ; Get directory listing.
  883. DIRECT    PROC    NEAR
  884.     mov ah,dosver        ; See what level of DOS we're at.
  885.     int dos
  886.     cmp al,0        ; Level 2.0 or above?
  887.     jne dir4        ; Yes - get directory the easy way.
  888.     mov comand.cmcr,1    ; Allow plain CR (so DIR == DIR *.*).
  889.     mov ah,cmifi        ; Get input file spec.
  890.     mov dx,offset fcb    ; Give the address for the FCB.
  891.     mov bx,offset filhlp3
  892.     call comnd
  893.      jmp r
  894.     mov ah,cmcfm        ; Parse a confirm.
  895.     call comnd
  896.      jmp r
  897.     mov comand.cmcr,0    ; Reset this. 
  898.     push es
  899.     mov ax,ds
  900.     mov es,ax
  901.     mov temp1,0FFH
  902.     mov di,offset nambuf
  903. dir0:    call getfn        ; Get a matching file name.
  904.     cmp al,0FFH        ; Retcode -- are we done?
  905.     je dir1            ; Yes, just leave.
  906.     call dumpit        ; Print it or dump to buffer.
  907.     jmp dir0
  908. dir1:    pop es
  909.     jmp rskp
  910.  
  911. dir4:    mov si,offset cmspbuf    ; command processor
  912.     mov di,offset dirnam
  913. dir5:    lodsb            ; get a byte
  914.     or al,al
  915.     jz dir6            ; stop on the null
  916.     stosb            ; otherwise copy it in
  917.     jmp dir5        ; and keep going
  918. dir6:    mov si,offset dircmd    ; add directory command to it
  919.     mov cx,dirclen
  920.     rep movsb
  921.     mov ah,cmtxt        ; parse with cmtxt so we can have paths...
  922.     mov bx,di        ; next available byte
  923.     mov dx,offset filwmsg    ; In case user wants help. 
  924.     call comnd
  925.      jmp r
  926.     mov cl,ah
  927.     mov ch,0        ; length of name
  928.     sub di,offset dirnam    ; compute # of bytes used
  929.     add cx,di
  930.     mov si,offset dirnam    ; dir cmd
  931.     jmp crun        ; join run cmd from there.
  932. DIRECT    ENDP
  933.  
  934. getfn:    cmp temp1,0FFH
  935.     jne gtfn1
  936.     mov ah,sfirst        ; Any matches?
  937.     mov dx,offset fcb
  938.     int dos
  939.     cmp al,0FFH        ; Means no matches.
  940.     je gtfn5
  941.     call savfcb
  942.     mov temp1,0
  943.     jmp gtfn4
  944. gtfn1:    cmp flags.wldflg,0FFH    ; Wilcard seen?
  945.     je gtfn2        ; Yes, get next file.
  946.     mov al,0FFH        ; No, set retcode.
  947.     ret
  948. gtfn2:    call rstfcb
  949.     mov ah,snext
  950.     mov dx,offset fcb
  951.     int dos
  952.     cmp al,0        ; Any more matches?
  953.     je gtfn3        ; Yes keep going.
  954.     mov al,0FFH        ; OK return code.
  955.     ret
  956. gtfn3:    call savfcb
  957. gtfn4:    push di
  958.     mov si,offset buff    ; Data is here.
  959.     mov di,offset fcb    ; Copy to here.
  960.     mov cx,37
  961.     repne movsb
  962.     pop di
  963.     call nicnam        ; Make name nice for printing.
  964.     mov al,0
  965.     ret
  966. gtfn5:    mov ah,prstr        ; Don't print if a server. 
  967.     mov dx,offset erms32    ; Say no matches.
  968.     int dos
  969.     mov al,0FFH        ; Failure return code.
  970.     ret
  971.  
  972. savfcb:    push di
  973.     mov si,offset fcb    ; Data is here.
  974.     mov di,offset cpfcb    ; Copy to here.
  975.     mov cx,37
  976.     repne movsb
  977.     pop di
  978.     ret
  979.  
  980. rstfcb:    push di
  981.     mov si,offset cpfcb    ; Data is here.
  982.     mov di,offset fcb    ; Copy to here.
  983.     mov cx,37
  984.     repne movsb
  985.     pop di    
  986.     ret
  987.  
  988. nicnam:    mov al,CR        ; Add CRLF before print names
  989.     stosb
  990.     mov al,LF
  991.     stosb
  992.     mov cx,8
  993.     mov si,offset fcb+1
  994.     repne movsb        ; Get the file name.
  995.     mov al,' '
  996.     stosb
  997.     mov cx,3
  998.     repne movsb
  999.     mov al,tab
  1000.     stosb
  1001.     mov al,' '
  1002.     stosb
  1003.     mov ah,openf
  1004.     mov dx,offset fcb
  1005.     int dos    
  1006.     mov bx,offset fcb+18    ; Get hi order word of file size.
  1007.     mov ax,[bx]
  1008.     mov dx,ax
  1009.     mov bx,offset fcb+16    ; Get lo order word.
  1010.     mov ax,[bx]
  1011.     call nout2x        ; Get it in decimal. 
  1012.     mov al,tab
  1013.     stosb
  1014.     mov al,' '
  1015.     stosb
  1016.     mov ah,0
  1017.     mov si,offset fcb+20
  1018.     lodsb
  1019.     mov fildat+1,al
  1020.     lodsb
  1021.     mov fildat,al        ; Date field of fcb.
  1022.     mov cl,5
  1023.     shr fildat+1,cl
  1024.     and fildat,1
  1025.     mov cl,3
  1026.     shl fildat,cl
  1027.     mov al,fildat
  1028.     or al,fildat+1        ; Get the month field.
  1029.     cmp al,9
  1030.     jg nic0
  1031.     push ax
  1032.     mov al,' '
  1033.     stosb
  1034.     pop ax
  1035. nic0:    call nout2        ; Make it decimal.
  1036.     mov al,'-'
  1037.     stosb
  1038.     mov si,offset fcb+20    ; Get date field.
  1039.     lodsb
  1040.     and al,1FH
  1041.     cmp al,10        ; Only one digit?
  1042.     jge nic0x
  1043.     push ax
  1044.     mov al,'0'        ; Make it two digits.
  1045.     stosb
  1046.     pop ax
  1047. nic0x:    call nout2        ; Make it decimal.
  1048.     mov al,'-'
  1049.     stosb
  1050.     mov si,offset fcb+21    ; Get the year field.
  1051.     lodsb
  1052.     shr al,1
  1053.     add al,80
  1054.     cmp al,100        ; At the year 2000 or above?
  1055.     js nic0y        ; No, just go on.
  1056.     sub al,100        ; Go back to two digits.
  1057. nic0y:    cmp al,10        ; Only one digit?
  1058.     jge nic0z
  1059.     push ax
  1060.     mov al,'0'        ; Make it two digits.
  1061.     stosb
  1062.     pop ax
  1063. nic0z:    call nout2        ; Make it decimal.
  1064.     mov al,tab
  1065.     stosb
  1066.     mov si,offset fcb+23    ; Get time field of fcb.
  1067.     lodsb
  1068.     mov cl,3        ; Get the hour field.
  1069.     shr al,cl
  1070.     mov tmp,'a'        ; For AM.
  1071.     cmp al,12        ; Before noon?
  1072.     jl nic1
  1073.     mov tmp,'p'        ; It's PM.
  1074.     je nic1            ; Don't change "12" to "0".
  1075.     sub al,12        ; Use a 12 hr. clock.
  1076. nic1:    cmp al,0        ; Just after midnight?
  1077.     jne nic1x
  1078.     add al,12        ; Make it "12" instead of "0".
  1079. nic1x:    cmp al,10        ; Pad with a space?
  1080.     jge nic2
  1081.     push ax
  1082.     mov al,' '
  1083.     stosb
  1084.     pop ax
  1085. nic2:    call nout2        ; Make it decimal.
  1086.     mov al,':'        ; Separate hours and minutes.
  1087.     stosb
  1088.     mov si,offset fcb+23    ; Get the minutes field.
  1089.     lodsb
  1090.     and al,07
  1091.     mov cl,3
  1092.     shl al,cl
  1093.     mov ah,al
  1094.     mov si,offset fcb+22
  1095.     lodsb
  1096.     mov cl,5
  1097.     shr al,cl
  1098.     or al,ah
  1099.     mov ah,0
  1100.     cmp al,10        ; Would there be a leading zero.
  1101.     jge nic3
  1102.     push ax
  1103.     mov al,'0'
  1104.     stosb
  1105.     pop ax
  1106. nic3:    call nout2        ; Make it decimal.
  1107.     mov al,tmp        ; Add 'a' (AM) or 'p' (PM).
  1108.     stosb
  1109.     mov ah,closf
  1110.     mov dx,offset fcb
  1111.     int dos
  1112.     ret
  1113.  
  1114. ; For now, just print it.
  1115. dumpit:    mov al,'$'
  1116.     stosb
  1117.     mov ah,prstr
  1118.     mov dx,offset nambuf
  1119.     int dos
  1120.     mov di,offset nambuf
  1121.     ret
  1122.  
  1123. ; push to an inferior command parser
  1124. ; entry fpush (fast push...) pushes without waiting for a confirm.
  1125. ; returns rskp.
  1126. dopush    proc    near
  1127.     cmp    dosnum,0        ; < 2.0 ?
  1128.     jne    dopus1            ; no, go on
  1129.     mov    dx,offset erms34
  1130.     mov    ah,prstr
  1131.     int    dos
  1132.     jmp    rskp
  1133. dopus1:    mov    ah,cmcfm
  1134.     call    comnd
  1135.      jmp    r
  1136. fpush:    mov    si,offset cmspbuf    ; name of parser
  1137.     push    si            ; save beginning
  1138.     sub    cx,cx            ; initial length
  1139. dopus2:    lodsb
  1140.     inc    cx            ; count this
  1141.     or    al,al            ; at end?
  1142.     jnz    dopus2            ; no, keep going
  1143.     pop    si            ; restore cmd
  1144.     dec    cx            ; this is incremented one over
  1145.     jmp    short crun        ; go run it
  1146. dopush    endp
  1147.  
  1148. ; crun - run an arbitrary program.  Enter with si/address of whole
  1149. ; cmd, cx/length of cmd.
  1150. CRUN    proc    near
  1151.     push cx            ; save length of cmd
  1152.     mov ax,ds
  1153.     mov es,ax        ; address dest segment
  1154.     mov di,offset nambuf
  1155.     rep movsb        ; copy command so we can mess with it
  1156.     pop cx
  1157.     mov si,offset nambuf    ; point to command
  1158.     jmp short run3        ; and join run code
  1159. CRUN    ENDP
  1160.  
  1161. RUN    PROC    NEAR
  1162.     cmp dosnum,0
  1163.     jne run1
  1164.     mov ah,prstr
  1165.     mov dx,offset erms34    ; Complain.
  1166.     int dos
  1167.     jmp rskp
  1168. run1:    mov ah,cmtxt        ; Get program name.
  1169.     mov bx,offset nambuf    ; Convenient buffer.
  1170.     mov dx,offset filmsg    ; In case user wants help.
  1171.     call comnd
  1172.      nop
  1173.      nop
  1174.      nop
  1175.     cmp ah,0
  1176.     jne run2
  1177.     mov ah,prstr
  1178.     mov dx,offset erms35
  1179.     int dos
  1180.     jmp rskp
  1181. run2:    mov cl,ah
  1182.     mov ch,0
  1183.     mov si,offset nambuf
  1184.  
  1185. ; alternate entry if cmd is already known.  Source cmd ptr in si
  1186. ; is trashed.
  1187. run3:    mov bx,cx
  1188.     mov byte ptr [si+bx],cr    ; end string with a cr for dos.
  1189.     mov di,offset cmdnam
  1190.     mov ax,ds
  1191.     mov es,ax
  1192. run4:    lodsb
  1193.     cmp al,' '
  1194.     jne run5
  1195.     dec si            ; back up over space
  1196.     jmp short run6        ; and exit loop
  1197. run5:    stosb
  1198.     loop run4
  1199. run6:    mov byte ptr [di],0    ; terminate string
  1200.     dec si            ; point back a byte into argument
  1201.     mov [si],cl        ; put length of argument here
  1202.     mov exearg+2,si        ; pointer to argument string
  1203.     mov exearg+4,ds        ; segment of same
  1204.     inc si            ; pass length over
  1205.     mov al,1        ; scan leading separators
  1206.     mov di,offset exefcb    ; parse into this fcb
  1207.     mov ah,prsfcb
  1208.     int dos            ; go parse the fcb
  1209.     mov al,1        ; scan leading separators
  1210.     mov di,offset exefcb2    ; second fcb to fill
  1211.     mov ah,prsfcb
  1212.     int dos            ; parse the fcb
  1213.     mov es,psp        ; point to psp again
  1214.     mov ax,es:[env]        ; get environment ptr
  1215.     mov exearg,ax        ; put into argument block
  1216.     mov bx,offset stk + 15    ; end of pgm
  1217.     mov cl,4
  1218.     shr bx,cl        ; compute # of paragraphs in last segment
  1219.     mov ax,seg stack    ; end of kermit
  1220.     sub ax,psp        ; minus beginning...
  1221.     add bx,ax        ; # of paragraphs occupied
  1222.     mov ah,setblk
  1223.     int dos
  1224.     jc run7            ; nope...
  1225.     mov ax,ds
  1226.     mov es,ax        ; put es segment back
  1227.     mov ax,offset cmdnam    ; point to cmd name again
  1228.     call spath        ; look for it
  1229.     jc run8            ; not found, go complain
  1230.     mov dx,ax        ; point to command name
  1231.     mov al,0        ; load and execute...
  1232.     mov ah,exec
  1233.     mov bx,offset exearg    ; and to arguments
  1234.     mov ssave,sp        ; save stack ptr
  1235.     int dos            ; go run the program
  1236.     mov ax,seg datas
  1237.     mov ds,ax        ; reset data segment
  1238.     mov ax,seg stack
  1239.     mov ss,ax        ; and stack segment
  1240.     mov sp,ssave        ; restore stack ptr
  1241.     mov ah,setdma
  1242.     mov dx,offset buff
  1243.     pushf            ; save flags
  1244.     int dos            ; restore dma address!!
  1245.     popf            ; recover flags
  1246.     jc run8            ; error, handle.
  1247.     jmp rskp        ; ok, return
  1248. run7:    mov ah,prstr
  1249.     mov dx,offset erms36
  1250.     int dos
  1251.     jmp rskp
  1252. run8:    mov ah,prstr
  1253.     mov dx,offset erms37
  1254.     int dos
  1255.     jmp rskp
  1256. RUN    ENDP
  1257.  
  1258. ; the show command
  1259. showcmd    proc    near
  1260.     mov    ah,cmkey
  1261.     mov    dx,offset shotab
  1262.     xor    bx,bx            ; no canned help
  1263.     call    comnd
  1264.      jmp    r
  1265.     call    bx            ; call the handler
  1266.      jmp    r
  1267.     jmp    rskp            ; and return
  1268. showcmd    endp
  1269.  
  1270. intbrk:    cmp flags.debug,1    ; Debug mode?
  1271.     je intb1        ; Yes, then don't ignore the ^C.
  1272.     push ax
  1273.     push ds
  1274.     mov ax,seg datas
  1275.     mov ds,ax
  1276.     mov flags.cxzflg,'C'    ; Say we saw a ^C.
  1277.     mov pack.state,'A'    ; Set the state to abort.
  1278.     pop ds
  1279.     pop ax
  1280.     iret
  1281. intb1:    jmp in3ad        ; Original break interrupt address.
  1282.  
  1283. NOUT2     PROC    NEAR
  1284.     push ax
  1285.     push dx
  1286.     mov temp,10        ; Divide quotient by 10.
  1287.     cwd            ; Convert word to doubleword.
  1288.     div temp        ; AX <-- Quo, DX <-- Rem.
  1289.     cmp ax,0        ; Are we done?    
  1290.     jz nout0        ; Yes.
  1291.     call nout2        ; If not, then recurse.
  1292. nout0:    add dl,'0'        ; Make it printable.
  1293.     mov temp,ax
  1294.     mov al,dl
  1295.     stosb
  1296.     mov ax,temp
  1297.     pop dx
  1298.     pop ax
  1299.     ret            ; We're done. [21c]
  1300. NOUT2    ENDP
  1301.  
  1302. NOUT2X     PROC    NEAR
  1303.     push ax
  1304.     push dx
  1305.     push cx
  1306.     mov temp,10        ; Divide quotient by 10.
  1307.     div temp        ; AX <-- Quo, DX <-- Rem.
  1308.     mov cx,dx        ; Remember the remainder.
  1309.     cmp ax,0        ; Are we done?    
  1310.     jz nout0x        ; Yes.
  1311.     mov dx,0
  1312.     call nout2        ; If not, then recurse.
  1313. nout0x:    add cl,'0'        ; Make it printable.
  1314.     mov temp,ax
  1315.     mov al,cl
  1316.     stosb
  1317.     mov ax,temp
  1318.     pop cx
  1319.     pop dx
  1320.     pop ax
  1321.     ret            ; We're done. [21c]
  1322. NOUT2X    ENDP
  1323.  
  1324. SPATH    proc    near
  1325. ; enter with ax/ ptr to file name.  Searches path for given file,
  1326. ; returns with ax/ ptr to whole name, or carry on if file isn't
  1327. ; to be found.
  1328.     push    es
  1329.     mov    bx,ds
  1330.     mov    es,bx            ; address data segment
  1331.     mov    bx,ax            ; convenient place to keep this
  1332.     call    isfile            ; does it exist as it is?
  1333.     mov    ax,bx            ; ifso, just return original name
  1334.     jc    spath0            ; nope...
  1335.     pop    es
  1336.     ret
  1337. spath0:    mov    si,ax
  1338.     mov    di,offset tfile        ; place to copy to
  1339.     mov    dl,0            ; no '\' seen yet
  1340. spath1:    lodsb
  1341.     stosb
  1342.     cmp    al,'/'            ; contain path characters?
  1343.     je    spath1a
  1344.     cmp    al,'\'
  1345.     jne    spath2            ; no, keep going
  1346. spath1a:mov    dl,1            ; remember we've seen them
  1347. spath2:    or    al,al
  1348.     jnz    spath1            ; copy name in
  1349.     or    dl,dl            ; look at flag
  1350.     jnz    spath3            ; path embedded, file not there, fail
  1351. ; no path, keep going
  1352. spath3:    mov    si,offset pthbuf    ; path definition
  1353.     cmp    byte ptr [si],0        ; empty path?
  1354.     jne    spath4            ; no, keep going
  1355.     mov    ah,gcd            ; get current dir
  1356.     mov    dl,0            ; for default drive
  1357.     mov    si,offset defpth+1    ; place to put it
  1358.     int    dos
  1359.     mov    si,offset defpth    ; point to the path
  1360. spath4:    cmp    byte ptr [si],0        ; null, exit loop
  1361.     je    spath9
  1362.     mov    di,offset tfile        ; place to put name
  1363. spath5:    lodsb                ; get a byte
  1364.     cmp    al,';'            ; end of this part?
  1365.     je    spath7            ; yes, break loop
  1366.     cmp    al,0            ; maybe end of string?
  1367.     jne    spath6            ; no, keep going
  1368.     dec    si            ; back up over it
  1369.     jmp    short spath7        ; and break loop
  1370. spath6:    stosb                ; else stick in dest string
  1371.     jmp    spath5            ; and continue
  1372. spath7:    push    si            ; save this ptr
  1373.     mov    si,bx            ; this is user's file name
  1374.     cmp    byte ptr [di-1],'/'    ; does it end with switch char?
  1375.     je    spath8            ; yes, don't put one in
  1376.     mov    al,'\'            ; how about this one?
  1377.     cmp    byte ptr [di-1],al
  1378.     je    spath8            ; yes, don't put it in.
  1379.     stosb                ; else add one
  1380. spath8:    lodsb
  1381.     stosb
  1382.     or    al,al
  1383.     jnz    spath8            ; copy rest of name
  1384.     pop    si            ; restore pos in path def
  1385.     mov    ax,offset tfile
  1386.     call    isfile            ; is it a file?
  1387.     jc    spath4            ; no, keep looking
  1388.     mov    ax,offset tfile
  1389.     pop    es
  1390.     ret                ; return success (carry off)
  1391. spath9:    pop    es            ; restore this
  1392.     stc                ; no file found
  1393.     ret
  1394. spath    endp
  1395.  
  1396.  
  1397. isfile    proc    near
  1398. ; returns carry off if the file pointed to by ax exists
  1399.     mov    dx,ax            ; copy ptr
  1400.     mov    al,0            ; don't change anything
  1401.     mov    ah,chmod
  1402.     int    dos
  1403.     ret                ; dos sets carry
  1404. isfile    endp
  1405.  
  1406. ; Jumping to this location is like retskp.  It assumes the instruction
  1407. ;   after the call is a jmp addr.
  1408.  
  1409. RSKP    PROC    NEAR
  1410.     pop bp
  1411.     add bp,3
  1412.     push bp
  1413.     ret
  1414.  
  1415. RSKP    ENDP
  1416.  
  1417. ; Jumping here is the same as a ret.
  1418.  
  1419. R    PROC    NEAR
  1420.     ret
  1421. R    ENDP
  1422.  
  1423. code     ends            ; End of code section.
  1424.     end    start
  1425.